next up previous contents index
Next: BUGS Up: ZMAPQTL Previous: REFERENCES   Contents   Index


CAVEATS

Model 7 has not been extensively tested. Remember that you will need to run Zmapqtl with some other model (say 3 or 6) and then run Eqtl prior to using model 7.

Model 8 requires a prior run of Zmapqtl and Eqtl as well. There is a shell script called Model8.csh in the scripts subdirectory that allows you to easily iterate using model 8. Try using it to see whether your set of cofactors (or estimated QTL) becomes stable after a few iterations. A low threshold may lead to adding and dropping putative QTL over consecutive analyses using Model 8. Here is the shell script:

        #!/usr/bin/csh
        #
        #  Run Model 8 iteration
        #           Copyright 2001 Christopher J. Basten
        #   Usage:
        #   Model8  bindir  stem   siglevel  iterations  max_nbp
        #     bindir is the binary subdirectory
        #     stem is the filename stem
        #     siglevel  is the significance level to declare a QTL
        #     iterations is the number of iterations
        #     max_nbp is the maximal number of background parameters.
        #
        if ( $1 == '-h' ) then
        echo "    Usage:  Model8.csh bindir  stem   siglevel  iterations  max_nbp"
        echo "Where"
        echo "        bindir  = QTL Cart. binary directory"
        echo "          stem  = filename stem"
        echo "      siglevel  = Significance level to declare a QTL"
        echo "    iterations  = number of iterations"
        echo "       max_nbp  = maximal number of background parameters"
        echo " "
        echo "Now exiting"
        exit
        endif
        set bindir=$1
        set stem=$2
        set siglevel=$3
        set iterations=$4
        set maxnbp=$5
        $bindir/Qstats -X $stem -A -V
        $bindir/Zmapqtl -A -V -M 3
        $bindir/Eqtl -A -V -S $siglevel
        #
        #  Save the original files
        #
        /usr/bin/mv $stem.eqt $stem.eqt.0
        /usr/bin/mv $stem.z $stem.z.0
        /usr/bin/cp $stem.sr $stem.sr.0
        #
        #  Use model 8 iteratively with cofactors from previous run.
        #
        set i=1
        while ( $i < $iterations )
        echo "Doing iteration $i"
        $bindir/Zmapqtl -A -V -M 8 -n $maxnbp
        /usr/bin/rm $stem.sr 
        $bindir/Eqtl -A -V -S $siglevel
        /usr/bin/cp $stem.sr $stem.sr.$i
        /usr/bin/mv $stem.eqt $stem.eqt.$i
        /usr/bin/mv $stem.z $stem.z.$i
        @ i++
        end
        /usr/bin/rm $stem.sr 
        echo "Finished"

The above script has been translated into Perl to make it more useful. The Model8.pl script can take command line parameters and is self-documenting.



Christopher Basten 2002-03-27